visit definition with a contract about racket-mode

[greghendershott]

I'd tested on procedures defined with define/contract and plain provide, which worked.

But I confirm what you're reporting, with an example using (provide/contract) or (provide (contract-out ..)).

The problem is that we definitely do want source-id in the case of a (provide (rename-out ...)). In that case, nominal-source-id is the renamed/provided thing, and source-id is how it was actually defined.

In other words, identifier-binding seems to behave "backwards" for contract-out vs. rename-out. :(

Even worse, there's the case of (provide (contract-out [rename -FOO foo (-> any)])) -- that is, both rename and contract. In that case source-id is something like 'provide/contract-id-foo.13, nominal-source-id is foo, and neither of those is the -FOO identifier used at the definition site.

Maybe I need to try finding all 3 of the possibilities -- the value from the Emacs buffer, source-id, and nominal-source-id -- in the source file, until one succeeds (or none do)?? That seems a bit kludgy, but maybe it's the only way to accomplish this. I think I'll post to the Racket mailing list to ask.

---

;;; provide.rkt
#lang racket

(define (f)
  0)
(provide f)

(define (-r)
  0)
(provide (rename-out [-r r]))

(define/contract (dc)
  (-> any)
  0)
(provide dc)

(define (pc)
  0)
(provide (contract-out [pc (-> any)]))

(define (-pcr)
  0)
(provide (contract-out [rename -pcr pcr (-> any)]))

;;; some-other-file.rkt
#lang racket
(require "provide.rkt")
(pretty-print
 (for/list ([sym '(f r dc pc pcr)])
   (match (identifier-binding (namespace-symbol->identifier sym))
     [(list source-mpi source-id
            nominal-source-mpi nominal-source-id
            source-phase import-phase nominal-export-phase)
      (list sym "source" source-id "nominal" nominal-source-id)])))

;; ==>
;; '((f "source" f "nominal" f)
;;   (r "source" -r "nominal" r)
;;   (dc "source" dc "nominal" dc)
;;   (pc "source" provide/contract-id-pc.9 "nominal" pc)
;;   (pcr "source" provide/contract-id-pcr.13 "nominal" pcr))

[greghendershott]

Note: Although commit 0115d51 fixes the specific issue originally reported, it doesn't handle the contract-out plus rename permutation I discussed above. Handling that, if possible at all, will require another approach.

[greghendershott]

Commit 1af7969 adds handing the renaming/contracting provides.