Easier ad hoc perSystem definition about flake-parts

[roberth]

Would be good if I could just do perSystem = { system, ... }: { foo = ... } and get flake.foo.x86_64-linux.

This would require the definition of flake to scan each config of allSystems, which is too strict.
Also many options in perSystem are not meant to be public, so for these reasons, it can't be quite as simple as that.

With #63 the following should do the trick:

{
  transposition.foo.adHoc = true;
  perSystem = { ... }: {
    foo = ...;
  };
}

I'm not adding that example to the readme though, because I want to encourage users to write proper options; not to copy this kind of bad example.

[shlevy]

Makes sense, thanks!

[shlevy]

@roberth Do you think it might be possible to at least lower the boilerplate to add a new proper option? Some simple way to say "I want to simultaneously define a perSystem option, and map it to a new flake attribute set option keyed on system and sharing a common description"?

[roberth]

Something in the style of mkRenamedOptionModule would be possible, but I didn't write it because

• Transposition is the problem and it should be removed from the next version of flakes
• We shouldn't be adding many ad hoc attributes
• The indirection will make the code a bit harder to understand
• The description isn't actually common, because of the transposition.

I've made it about as easy as possible to make a really ad hoc declaration; just two lines. Apparently your use case is not as ad hoc. What is your actual use case?

[shlevy]

Ah, sorry, this was meant to be a question about what to do when it's not ad hoc. E.g. if I look at apps.nix, it seems like I should be able to just write something like

{
  options.perSystemFlakeOptions.apps = mkPerSystemFlakeOption
      ({ config, system, ... }: mkOption {
          type = types.lazyAttrsOf appType;
          default = { };
          description = ''
            Programs runnable with nix run <literal>.#&lt;name></literal>.
          '';
          example = lib.literalExpression or lib.literalExample ''
            {
              default.program = "''${config.packages.hello}/bin/hello";
            }
          '';
        }
      );
}

in place of

{
  options = {
    flake = mkSubmoduleOptions {
      apps = mkOption {
        type = types.lazyAttrsOf (types.lazyAttrsOf appType);
        default = { };
        description = ''
          Programs runnable with nix run <literal>.#&lt;name></literal>.
        '';
        example = lib.literalExpression or lib.literalExample ''
          {
            x86_64-linux.default.program = "''${config.packages.hello}/bin/hello";
          }
        '';
      };
    };

    perSystem = mkPerSystemOption
      ({ config, system, ... }: {
        options = {
          apps = mkOption {
            type = types.lazyAttrsOf appType;
            default = { };
            description = ''
              Programs runnable with nix run <literal>.#&lt;name></literal>.
            '';
            example = lib.literalExpression or lib.literalExample ''
              {
                default.program = "''${config.packages.hello}/bin/hello";
              }
            '';
          };
        };
      });

  };
  config = {
    flake.apps =
      mapAttrs
        (k: v: v.apps or { })
        config.allSystems;

    perInput = system: flake:
      optionalAttrs (flake?apps.${system}) {
        apps = flake.apps.${system};
      };

  };
}

and still get all the same results.

[roberth]

Ah ok 👍

I'm a bit cautious about making option declarations dynamic, even though adHoc = true shows that it's possible in at least some cases. I think one problem may be the docs generation. Only "static" modules show up in the docs. Once you declare submodule options via a module added in config, they won't be picked up.

So I really think it'd have to be

Something in the style of mkRenamedOptionModule

or, basically, turn the whole apps.nix (or packages.nix or ...) module into a function and parameterize it to abstract all the specifics.

  config = {
    flake.apps =
[...]

Nitpicking, but this part has been replaced by config.transposition.apps = { };

[shlevy]

@roberth Created #64 for this