Hetionet to cytoscape problems about hetionet

[gsummer]

Hi all! Sorry about the lack of updates on cyNeo4j, I am finishing up my thesis. Two comments: 1. There is a dev version on github (https://github.com/gsummer/cyNeo4j/releases/tag/v1.3dev) that supports the labels and fixes a lot of issues with arrays. 2. Speaking of arrays: I'll see if I can add path support over the next days. I'll put it up as another dev version and let you know! Any testing would be appreciated! Georg

[dhimmel]

@jromanowska cool query!

Unfortunately, I don't think @gsummer is actively maintaining cyNeo4j anymore. We've also run into the issue that cyNeo4j doesn't support exporting paths to Cytoscape (see cyNeo4j/cyNeo4j#14). We've engineered a partial workaround, where you append the following to a query returning paths:

WITH relationships(path) AS rels
UNWIND rels AS rel
RETURN DISTINCT startNode(rel) AS source, endNode(rel) AS target, rel AS relationship

So the following query should work with cyNeo4j:

MATCH path = allShortestPaths((node1:Gene)-[*..3]-(node2:PharmacologicClass))
WHERE
  node1.name = 'ESRRG' AND
  node2.name STARTS WITH 'Vitamin'
WITH relationships(path) AS rels
UNWIND rels AS rel
RETURN DISTINCT startNode(rel) AS source, endNode(rel) AS target, rel AS relationship

This will return all nodes and relationships in the matched paths. Note that the Neo4j browser shows all relationships between returned nodes by default (even if those relationships were not requested). This option is controlled by the AUTO-COMPLETE toggle. So Cytoscape will receive just the relationships in the paths, i.e. AUTO-COMPLETE set to OFF.

Also unfortunately, there is a separate cyNeo4j issue where nodes don't retain their labels (i.e. node types, see cyNeo4j/cyNeo4j#15). Therefore, you may need to do a little extra work to get reverse engineer the node types in Cytoscape.

Good luck! We'd love to see what you come up with.

[dhimmel]

Also note that (in this instance), the above query can be simplified by removing allShortestPaths. Since the shortest path between ESRRG and a Vitamin* is 3, this is just returning all paths of length 3.

[jromanowska]

That worked, thank you! I see I need to read more about Cypher then ;)

And by the way - have you tried visualizing your networks in R?

[jromanowska]

@gsummer - great that you're still working a bit on this app. I'll give the dev version a try.

However, there is another issue - on Neo4j there is an "auto-complete" option, while this doesn't seem to be on when I use cyNeo4j, so when getting a union of two queries, there are many edges that are missing.

[dhimmel]

@gsummer good to know about the dev version. Best of luck with your PhD. I know the terror/joy of the last few months of a dissertation. Happy to test whenever.

on Neo4j there is an "auto-complete" option, while this doesn't seem to be on when I use cyNeo4j

@jromanowska the AUTO-COMPLETE feature of the Neo4j Browser is a frontend "extra". Since cyNeo4j interacts solely via Cypher queries, I don't think an AUTO-COMPLETE feature would be appropriate for cyNeo4j (since AUTO-COMPLETE is not part of Cypher).

However, you can make your query return all relationships between your selected nodes (source):

MATCH path = (node1:Gene)-[*..3]-(node2:PharmacologicClass)
WHERE
  node1.name = 'ESRRG' AND
  node2.name STARTS WITH 'Vitamin'
WITH nodes(path) AS nodes
UNWIND nodes AS node_set
WITH collect(DISTINCT node_set) AS node_set
MATCH (n1)-[rel]->(n2)
WHERE 
  n1 in node_set AND
  n2 in node_set
RETURN DISTINCT startNode(rel) AS source, endNode(rel) AS target, rel AS relationship

[jromanowska]

Forgot to write yesterday - it works, thank you! And thanks for explanation about the auto-complete option.

And btw, @gsummer - the developmental version of cyNeo4j works fine for me as well.

[dhimmel]

Great!