Example with ECR and docker_registry_image about terraform-provider-docker

[cosmotek]

Here's an example I got working:

locals {
  docker_image_name = "my_docker_image"
}

resource "aws_ecr_repository" "ecr_repo" {
  name                 = local.docker_image_name
  image_tag_mutability = "IMMUTABLE"

  image_scanning_configuration {
    scan_on_push = true
  }
}

resource "aws_ecr_repository_policy" "ecr_repo_policy" {
  repository = aws_ecr_repository.ecr_repo.name

  policy = <<EOF
{
    "Version": "2008-10-17",
    "Statement": [
        {
            "Sid": "new policy",
            "Effect": "Allow",
            "Principal": "*",
            "Action": [
                "ecr:GetAuthorizationToken",
                "ecr:GetDownloadUrlForLayer",
                "ecr:BatchGetImage",
                "ecr:BatchCheckLayerAvailability",
                "ecr:PutImage",
                "ecr:InitiateLayerUpload",
                "ecr:UploadLayerPart",
                "ecr:CompleteLayerUpload",
                "ecr:DescribeRepositories",
                "ecr:GetRepositoryPolicy",
                "ecr:ListImages",
                "ecr:DeleteRepository",
                "ecr:BatchDeleteImage",
                "ecr:SetRepositoryPolicy",
                "ecr:DeleteRepositoryPolicy"
            ]
        }
    ]
}
EOF
}

provider "docker" {
  registry_auth {
    address     = data.aws_ecr_authorization_token.container_registry_token.proxy_endpoint
    username = data.aws_ecr_authorization_token.container_registry_token.user_name
    password = data.aws_ecr_authorization_token.container_registry_token.password
  }
}

data "aws_ecr_authorization_token" "container_registry_token" {}
resource "time_static" "now" {}

resource "docker_registry_image" "my_docker_image" {
  name = "${aws_ecr_repository.ecr_repo.repository_url}:build-${time_static.now.unix}"

  build {
    context = "${path.module}/src"
    labels = {
      dir_sha1 = sha1(join("", [for f in fileset("${path.module}/src", "*") : filesha1("${path.module}/src/${f}")]))
    }
  }
}

[suzuki-shunsuke]

This may have nothing to do with the error, but your configuration file is wrong.

https://registry.terraform.io/providers/kreuzwerker/docker/latest/docs#config_file_content

Cannot be used with the username/password or config_file options.

[suzuki-shunsuke]

I could reproduce the error.

resource "docker_registry_image" "helloworld" {
  name = "something-amazing/helloworld:2.0"

  build {
    context = "context"
  }
}

data "aws_ecr_authorization_token" "token" {
}

provider "docker" {
  registry_auth {
    address  = "<aws account id>.dkr.ecr.ap-northeast-1.amazonaws.com"
    username = data.aws_ecr_authorization_token.token.user_name
    password = data.aws_ecr_authorization_token.token.password
  }
}

provider "aws" {
  region = "ap-northeast-1"
}

$ terraform version
Terraform v0.13.5
+ provider registry.terraform.io/hashicorp/aws v3.19.0
+ provider registry.terraform.io/kreuzwerker/docker v2.8.0

$ terraform apply
data.aws_ecr_authorization_token.token: Refreshing state...

An execution plan has been generated and is shown below.
Resource actions are indicated with the following symbols:
  + create

Terraform will perform the following actions:

  # docker_registry_image.helloworld will be created
  + resource "docker_registry_image" "helloworld" {
      + id            = (known after apply)
      + keep_remotely = false
      + name          = "something-amazing/helloworld:2.0"
      + sha256_digest = (known after apply)

      + build {
          + context    = "context:a1094ea0c6474f9d4eee107593ef19211a9009797363cd598a44daaf8abc75de"
          + dockerfile = "Dockerfile"
        }
    }

Plan: 1 to add, 0 to change, 0 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

docker_registry_image.helloworld: Creating...

Error: Error pushing docker image: Error response from daemon: Bad parameters and missing X-Registry-Auth: EOF

  on main.tf line 1, in resource "docker_registry_image" "helloworld":
   1: resource "docker_registry_image" "helloworld" {

[suzuki-shunsuke]

@antonbabenko

It succeeded to push a Docker image by adding the registry path to docker_registry_image's name.

resource "docker_registry_image" "helloworld" {
  # name = "something-amazing/helloworld:2.0"
  name = "<aws account id>.dkr.ecr.ap-northeast-1.amazonaws.com/something-amazing/helloworld:2.0"

  build {
    context = "context"
  }
}

[antonbabenko]

Thank you, this works as expected.

I have just updated the Terraform AWS Lambda module and reference to this provider - https://github.com/terraform-aws-modules/terraform-aws-lambda/pull/80/files#diff-b71ad04f644acd7192bbc30fcb3f747a785983233f38a333c93c9f4541f7989a