Can't compile with Xwidgets support about emacs-overlay

[terlar]

I think we need some more details, how are you using this expression, are you sure it is the result of this derivation that is used as your Emacs. If you do which emacs what do you see. I have verified that this works, see:

$ nix-shell -p 'emacsGit.override { withXwidgets = true; withGTK3 = true; }' --run 'emacs -Q --batch --eval "(message \\"%s\\" (featurep \'xwidget-internal))"'
t
$ nix-shell -p 'emacsGit' --run 'emacs -Q --batch --eval "(message \\"%s\\" (featurep \'xwidget-internal))"'
nil

[11111000000]

used simply as:

nixpkgs.overlays = [
    (import (builtins.fetchTarball {
      url = https://github.com/nix-community/emacs-overlay/archive/master.tar.gz;
    }))
  ];
....
systemPackages = with pkgs; [
      (emacsGit.override {        
        withXwidgets = true;
        withGTK3 = true;        
      })

[az@thinky:/etc/nixos]$ which emacs
/nix/var/nix/profiles/default/bin/emacs

and that emacs is 26
but I use

windowManager = {
      session = lib.singleton {
        name = "exwm";
        start = ''
          eval `dbus-launch --exit-with-session ${pkgs.emacsGit}/bin/emacs`
        '';
      };
    };

and M-x version shows GNU Emacs 28.0.50 (build 1, x86_64-pc-linux-gnu, GTK+ Version 3.24.13, cairo version 1.16.0)

[terlar]

That explains it, if you refer to it as ${pkgs.emacsGit} you are not using the overridden version of the package. Easiest is to provide another overlay that either overwrites the pkgs.emacsGit or adds a new pkgs.emacsGitWithXwidgets

If you add another overlay, such as:

nixpkgs.overlays = [
    (import (builtins.fetchTarball {
      url = https://github.com/nix-community/emacs-overlay/archive/master.tar.gz;
    }))
    (self: super: {
      emacsGit = super.emacsGit.override {        
        withXwidgets = true;
        withGTK3 = true;        
      };
    })
  ];
....
systemPackages = with pkgs; [
      emacsGit

then it should work.

or if you want to have both with/without Xwidgets you could define it as emacsGitWithXwidgets in the overlay and then refer to that package instead of emacsGit in both systemPackages and windowManager start eval ${pkgs.emacsGitWithXwidgets}.

The ugly solution that should also work would be:

windowManager = {
      session = lib.singleton {
        name = "exwm";
        start = ''
          eval `dbus-launch --exit-with-session ${pkgs.emacsGit.override { withXwidgets = true; withGTK3 = true; }}/bin/emacs`
        '';
      };
    };

or

windowManager = let
  emacs = pkgs.emacsGit.override {        
    withXwidgets = true;
    withGTK3 = true;        
  };
in {
      session = lib.singleton {
        name = "exwm";
        start = ''
          eval `dbus-launch --exit-with-session ${emacs}/bin/emacs`
        '';
      };
    };

Just to show that there is no specific magic going on, I hope this clarifies things a bit.

[adisbladis]

Closing since it seems this was a case of simple user-error :)