A simple ClojureScript interface to React.
Reagent provides a way to write efficient React components using (almost) nothing but plain ClojureScript functions.
- Detailed intro with live examples
- News
- Documentation, latest release
- Documentation, next release: API docs, Tutorials and FAQ
- Community discussion and support channels
- #reagent channel in Clojure Slack
- Commercial video material
- Learn Reagent Free, Learn Reagent Pro (Affiliate link, $30 discount)
- Learn Re-frame Free, Learn Re-frame Pro (Affiliate link, $30 discount)
- purelyfunctional.tv
- Lambda Island Videos
To create a new Reagent project using Leiningen template simply run:
lein new reagent myproject
If you wish to only create the assets for ClojureScript without a Clojure backend then do the following instead:
lein new reagent-frontend myproject
This will setup a new Reagent project with some reasonable defaults, see here for more details.
To use Reagent in an existing project you add this to your dependencies in project.clj:
And provide React using either npm (when using e.g. Shadow-cljs)
npm i react react-dom
or by adding Cljsjs React packages to your project:
[cljsjs/react "17.0.2-0"]
[cljsjs/react-dom "17.0.2-0"]
Note: Reagent is tested against React 17, but should be compatible with other versions.
Reagent uses Hiccup-like markup instead of React's sort-of html. It looks like this:
(defn some-component []
[:div
[:h3 "I am a component!"]
[:p.someclass
"I have " [:strong "bold"]
[:span {:style {:color "red"}} " and red"]
" text."]])Reagent extends standard Hiccup in one way: it is possible to "squeeze" elements together by using a > character.
[:div
[:p
[:b "Nested Element"]]]can be written as:
[:div>p>b "Nested Element"]Since version 0.8: The
:classattribute also supports collections of classes, and nil values are removed:[:div {:class ["a-class" (when active? "active") "b-class"]}]
You can use one component inside another:
(defn calling-component []
[:div "Parent component"
[some-component]])And pass properties from one component to another:
(defn child [name]
[:p "Hi, I am " name])
(defn childcaller []
[child "Foo Bar"])You mount the component into the DOM like this:
(defn mountit []
(rd/render [childcaller]
(.-body js/document)))assuming we have imported Reagent like this:
(ns example
(:require [reagent.core :as r]
[reagent.dom :as rd]))State is handled using Reagent's version of atom, like this:
(defonce click-count (r/atom 0))
(defn state-ful-with-atom []
[:div {:on-click #(swap! click-count inc)}
"I have been clicked " @click-count " times."])Any component that dereferences a reagent.core/atom will be automatically re-rendered.
If you want to do some setting up when the component is first created, the component function can return a new function that will be called to do the actual rendering:
(defn timer-component []
(let [seconds-elapsed (r/atom 0)]
(fn []
(js/setTimeout #(swap! seconds-elapsed inc) 1000)
[:div
"Seconds Elapsed: " @seconds-elapsed])))This way you can avoid using React's lifecycle callbacks like getInitialState and componentWillMount most of the time.
But you can still use them if you want to, either using reagent.core/create-class or by attaching meta-data to a component function:
(defonce my-html (r/atom ""))
(defn plain-component []
[:p "My html is " @my-html])
(def component-with-callback
(with-meta plain-component
{:component-did-mount
(fn [this]
(reset! my-html (.-innerHTML (rd/dom-node this))))}))See the examples directory for more examples.
React is pretty darn fast, and so is Reagent. It should even be faster than plain old javascript React a lot of the time, since ClojureScript allows us to skip a lot of unnecessary rendering (through judicious use of React's shouldComponentUpdate).
The ClojureScript overhead is kept down, thanks to lots of caching.
Code size is a little bigger than React.js, but still quite small. The todomvc example clocks in at roughly 79K gzipped, using advanced compilation.
The idea and some of the code for making components atom-like comes from pump. The reactive-atom idea (and some code) comes from reflex.
The license is MIT.
React
Typescript
Django
Laravel
Facebook
Microsoft
Google
Alibaba
D3
Tencent