Modifier. AddCustomAttribute() fails to add custom attribute to class methods about nemerle

[VladD2]

type.GetModifiers().AddCustomAttribute (<[ TestFixture ]>);

You should use full name of attribut or open appropriate namespace in file which contains macro.

def methods = type.GetMethods(BindingFlags.Instance | BindingFlags.Public);

The GetMethods() method work only at MacroPhase.WithTypedMembers phase (as, since it return typed members).
You should use MacroPhase.WithTypedMembers, or work with antyped AST (through TypeBuilder.Ast).

This version work well:

// Macro.n

using Nemerle;
using Nemerle.Collections;
using Nemerle.Compiler;
using Nemerle.Compiler.Parsetree;
using Nemerle.Compiler.Typedtree;
using Nemerle.Utility;

using System;
using System.Collections.Generic;
using System.Linq;

namespace TestMacro
{
  [MacroUsage(MacroPhase.WithTypedMembers, MacroTargets.Class)]
  macro UnitTestFixture(typeBuilder : TypeBuilder)
  {
    UnitTestFixtureImpl.DoTransform(Macros.ImplicitCTX(), typeBuilder)
  }

  module UnitTestFixtureImpl
  {
    public DoTransform(typer : Typer, typeBuilder : TypeBuilder) : void
    {
      Macros.DefineCTX(typer);
      typeBuilder.GetModifiers().AddCustomAttribute (<[ NUnit.Framework.TestFixtureAttribute ]>);

      def methods = typeBuilder.GetMethods(BindingFlags.Instance | BindingFlags.Public | BindingFlags.DeclaredOnly);

      foreach(method in methods)
        method.GetModifiers().AddCustomAttribute(<[ NUnit.Framework.TestAttribute ]>);      
    }
  }
}

// Test.n
using TestMacro;

[UnitTestFixture()]
public class OptionalHeaderTests
{
  public SomeTest() : void
  {            
  }
}

module Program
{
  Main() : void
  {
  }
}

[philiplaureano]

Thanks. What about Assembly-level meta attributes? Is there any way to use one attribute declaration such as:

[assembly:UnitTestSuite("MyNamespace.Tests.*")]

...to apply the [UnitTestFixture()] attribute to all types within a given namespace?

[VladD2]

Thanks. What about Assembly-level meta attributes?

Simply replace the MacroTargets.Class by MacroTargets.Assembly and remove the typeBuilder parameter:

using Nemerle;
using Nemerle.Collections;
using Nemerle.Compiler;
using Nemerle.Compiler.Parsetree;
using Nemerle.Compiler.Typedtree;
using Nemerle.Utility;

using System;
using System.Collections.Generic;
using System.Linq;

namespace TestMacro
{
  [MacroUsage(MacroPhase.WithTypedMembers, MacroTargets.Assembly)]
  macro UnitTestFixture()
  {
    UnitTestFixtureImpl.DoTransform(Macros.ImplicitCTX())
  }

  module UnitTestFixtureImpl
  {
    public DoTransform(typer : Typer) : void
    {
      Macros.DefineCTX(typer);

      def typeBuilders = typer.Manager.CoreEnv.NameTree.NamespaceTree.GetTypeBuilders(onlyTopDeclarations = true);

      foreach (typeBuilder in typeBuilders)
      {
        typeBuilder.GetModifiers().AddCustomAttribute (<[ NUnit.Framework.TestFixtureAttribute ]>);

        def methods = typeBuilder.GetMethods(BindingFlags.Instance | BindingFlags.Public | BindingFlags.DeclaredOnly);

        foreach(method in methods)
          method.GetModifiers().AddCustomAttribute(<[ NUnit.Framework.TestAttribute ]>);
      }
    }
  }
}

Note: If oyu specify "onlyTopDeclarations = false", you get all typebuilders including nested types.