Hatching about skia4delphi

[Echelon78]

Thank you very much for both examples. Before I could report the misalignment, there was a second, better, solution. Thank you very much.

[viniciusfbb]

Hi @Echelon78!
You can use the code:

uses
  System.Math.Vectors, Skia;

procedure Hatching(const ACanvas: ISkCanvas);
var
  paint: ISkPaint;
  lattice: TMatrix;
  bounds: TRectF;
begin
  paint := TSkPaint.Create;
  paint.Color := TAlphaColors.Black;
  lattice := TMatrix.CreateRotation(45) * TMatrix.CreateScaling(8, 8);
  paint.PathEffect := TSkPathEffect.Make2DLine(1, lattice);
  paint.AntiAlias := True;
  bounds := TRect.Create(0, 0, 250, 250);
  ACanvas.Clear(TAlphaColors.White);
  ACanvas.DrawRect(bounds, paint);
end;

Result:

[viniciusfbb]

This result is a little unexpected, the traces are not aligned with the rect bounds when compared to the fiddle result. Some differences with fiddle can occur because fiddle always uses the newest skia (the current version we use, the m88, is almost 1 year older). I'll be able to investigate this in the future, but for now this difference can easily be worked around by changing the previous code to:

uses
  System.Math.Vectors, Skia;

procedure Hatching(const ACanvas: ISkCanvas);
var
  paint: ISkPaint;
  lattice: TMatrix;
  bounds: TRectF;
begin
  paint := TSkPaint.Create;
  paint.Color := TAlphaColors.Black;
  lattice := TMatrix.CreateRotation(45) * TMatrix.CreateScaling(8, 8);
  paint.PathEffect := TSkPathEffect.Make2DLine(1, lattice);
  paint.AntiAlias := True;
  bounds :=  TRect.Create(0, 0, 250, 250);
  ACanvas.Clear(TAlphaColors.White);
  ACanvas.Save;
  try
    ACanvas.ClipRect(bounds);
    bounds.Inflate(8,8);
    ACanvas.DrawRect(bounds, paint);
  finally
    ACanvas.Restore;
  end;
end;

Result:

[viniciusfbb]

@Echelon78
Today I was doing other examples and I discovered by chance why our example was not working exactly like fiddle: although there is no documentation, TMatrix.CreateRotation works with radians and not with degree. So just add the DegToRad(, looking like this:

uses
  System.Math, System.Math.Vectors, Skia;

procedure Hatching(const ACanvas: ISkCanvas);
var
  paint: ISkPaint;
  lattice: TMatrix;
  bounds: TRectF;
begin
  paint := TSkPaint.Create;
  paint.Color := TAlphaColors.Black;
  lattice := TMatrix.CreateRotation(DegToRad(45)) * TMatrix.CreateScaling(8, 8);
  paint.PathEffect := TSkPathEffect.Make2DLine(1, lattice);
  paint.AntiAlias := True;
  bounds :=  TRect.Create(0, 0, 250, 250);
  ACanvas.Clear(TAlphaColors.White);
  ACanvas.Save;
  try
    ACanvas.ClipRect(bounds);
    bounds.Inflate(8,8);
    ACanvas.DrawRect(bounds, paint);
  finally
    ACanvas.Restore;
  end;
end;

Result:

[viniciusfbb]

Added this example in new Demo. :)